// 1. 플러그인 관리 (Spring Boot 등 플러그인 버전을 여기서 중앙 통제)
pluginManagement {
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
}

// 2. 의존성 관리 (버전 카탈로그)
dependencyResolutionManagement {
    // 하위 모듈들이 독단적으로 다른 저장소(repository)를 쓰는 것을 금지!
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        mavenCentral()
    }
    
    // '버전 카탈로그' 세팅 (라이브러리 메뉴판)
    versionCatalogs {
        create("libs") {
            // [버전 정의]
            version("springBoot", "4.0.3")
            version("springDependencyManagement", "1.1.7")
            version("lombok", "1.18.30")
            version("springdoc", "3.0.2")
            version("swaggerAnnotationsJakarta", "2.2.43")
            version("pitest", "1.19.1")
            version("pitestJunit5", "1.2.2")
            version("pitestPlugin", "1.19.0-rc.1")
            version("jqwik", "1.9.3")

            // [플러그인 정의]
            plugin("spring-boot", "org.springframework.boot").versionRef("springBoot")
            plugin("spring-dependency-management", "io.spring.dependency-management").versionRef("springDependencyManagement")
            plugin("pitest", "info.solidsoft.pitest").versionRef("pitestPlugin")

            // [라이브러리 정의]
            library("lombok", "org.projectlombok", "lombok").versionRef("lombok")
            library("springdoc-openapi-webmvc-ui", "org.springdoc", "springdoc-openapi-starter-webmvc-ui").versionRef("springdoc")
            library("swagger-annotations-jakarta", "io.swagger.core.v3", "swagger-annotations-jakarta").versionRef("swaggerAnnotationsJakarta")
            library("jqwik", "net.jqwik", "jqwik").versionRef("jqwik")
            library("pitest-junit5-plugin", "org.pitest", "pitest-junit5-plugin").versionRef("pitestJunit5")
        }
    }
}

rootProject.name = 'project-auth-server'

include("bootstrap")
include("domain")
include("application")
include("presentation")
include("infrastructure")